(define (integrate-series s)
  (define (coefficient stream n)
    (cons-stream (/ (stream-car stream) n)
                 (coefficient (stream-cdr stream) (+ n 1))))
  (coefficient s 1))

(define cosine-series
  (cons-stream 1 (scale-stream (integrate-series sine-series) -1)))

(define sine-series
  (cons-stream 0 (integrate-series cosine-series)))

(define (invert-unit-series s)
  (define x (cons-stream 1
                         (mul-series (scale-stream (stream-cdr s) -1)
                                     x)))
  x)

(define (mul-series a b)
  (cons-stream (* (stream-car a) (stream-car b))
               (add-streams (scale-stream (stream-cdr a)
                                          (stream-car b))
                            (mul-series a (stream-cdr b)))))

(define (div-series n d)
  (let ((c (stream-car d)))
    (let ((p (scale-stream d (/ 1 c))))
      (mul-series n
                  (scale-stream (invert-unit-series p) (/ 1 c))))))

(define tangent-series (div-series sine-series cosine-series))